Info
Sammeln
Dokumentation
Anleitungen
Schnittstellen
Prozessoren
Videochips
Soundchips
Computer
Videospiele


Locomotive Basic (Schneider/Amstrad CPC), Teil 1
Locomotive Basic 1.0
1. Einleitung

Basic ist eine sehr simple, dafür aber auch leicht erlernbare Programmiersprache. Im Gegensatz zu fast allen moderneren Sprachen ist Basic eine Interpretersprache. Das heißt, daß ein Programm, ein Programmteil oder auch nur ein einzelner Befehl jederzeit ausprobiert werden kann. Das Ergebnis kann sofort begutachtet werden.
So kann man Basic schon nach wenigen Minuten als Taschenrechner einsetzen, während andere Sprachen zuerst eine aufwendige Einarbeitung in Editor, Compiler und Entwicklungsumgebung voraussetzen.
Dadurch ist die Abarbeitungsgeschwindigkeit fertiger Basicprogramme aber auch nicht mit der von C- oder gar Assemblerprogrammen vergleichbar.
Locomotive Basic V1.0 ist der Basicdialekt des Amstrad / Schneider CPC 464. Es zählt zu den leistungsfähigeren Basics, enthält Kommandos für Sound und Grafik und enttäuscht auch nicht im Bezug auf die Ausführungsgeschwindigkeit. Allein der Editor erscheint durch die Anwendung eines Kopiercursors umständlicher als es eigentlich notwendig wäre.

1.1 Befehlsmodus

Der einfachste Einstieg in den Umgang mit Basic ist der Befehlsmodus. Er ist bei fast jedem Homecomputer direkt nach dem Einschalten verfügbar. Sie tippen einen Befehl ein, drücken am Ende die Eingabetaste und schon wird der Befehl ausgeführt.
In der Praxis wird der Befehlsmodus hauptsächlich für zwei Aufgaben genutzt: Erstens können Programme vom Befehlsmodus aus von einem Speichergerät geladen bzw. auf einem Speichergerät abgelegt werden, zweitens ist der Befehlsmodus ein sehr schöner Taschenrechner.

1.1.1 Laden und speichern von Programmen

Der CPC 464 hat bereits ein Datenkassettenlaufwerk eingebaut. Extern lässt sich zudem auch ein Diskettenlaufwerk anschließen.

LOAD
LOAD "[<programmname>"[,<adresse>]]

LOAD" lädt das erstbeste Programm von der Datenkassette. Wird ein Programmname angegeben, muß das von der Datasette eingespielte Programm genau diesen Namen haben. Die Angabe der Startadresse im Hauptspeicher ist nur bei Dateien möglich, die als Binärdateien gespeichert wurden.

RUN
RUN "[<programmname>"]

RUN" lädt das erstbeste Programm von der Datenkassette und startet es anschließend sofort. Durch die Angabe des Programmnamens muß das auf der Kassette gespeicherte Programm genau diesen Namen haben um geladen zu werden.

CHAIN, CHAIN MERGE
CHAIN "[<programmname>"][,<startzeilennummer>]
CHAIN MERGE "[<programmname>"][,<startzeilennummer>][,DELETE <von>-<bis>]

CHAIN lädt ein Programm von Datenkassette und verknüpft es mit dem bestehenden. Ein normaler CHAIN-Befehl hängt das geladene Programm an das bestehende an, CHAIN MERGE mischt beide Programme gemäß der Zeilennummern.
[Anmerkung: So ganz habe ich den Befehl mit meiner (französischen) Anleitung nicht kapiert. Ich werde da wohl irgendwann mal experimentieren müssen...]

SAVE
SAVE "[<programmname>"[,<option>][,<startadr>,<länge>[,<sprungadr>]]]

SAVE speichert das im Arbeitsspeicher befindliche Programm auf Kassette ab. Normalerweise ist die Angabe einer Option und der übrigen Parameter nicht erforderlich. Ein "A" als Option veranlasst den SAVE-Befehl, das Programm im Klartext zu speichern, während es normalerweise als Abbild des Programmspeichers abgelegt wird.
Mit der Option "P" können Sie Ihr Programm gegen Auflistung und Veränderung schützen. Ein so gespeichertes Programm kann nur noch geladen und gestartet werden. Da es keinen Weg zurück gibt, sollten Sie auf jeden Fall eine ungeschützte Version Ihrer Programme aufbewahren.
Falls Sie ein Maschinenspracheprogramm erstellt haben oder einfach einen Speicherbereich mit irgendwelchen Daten sichern wollen, benötigen Sie die Option "B". Hier müssen Sie zudem angeben, ab welcher Hauptspeicheradresse gespeichert werden soll und wieviele Bytes ab dieser Stelle aufs Band geschrieben werden sollen. Zudem können Sie eine Einsprungsadresse angeben, ab der das Maschinenspracheprogramm nach dem Laden gestartet werden soll.

SPEED WRITE
SPEED WRITE 0|1

Legt die Speichergeschwindigkeit der Datenkassette auf hohes Tempo (2000 Baud) fest (mit dem Wert 1) oder senkt sie wieder auf das normale Maß ab (Wert 0) (1000 Baud). Beim Laden wird die Geschwindigkeit, mit der die Datei gespeichert wurde automatisch erkannt.

CAT

CAT liest alle Programme, die vom Datenrekorder vorgespielt werden, prüft sie auf korrekte Speicherung und gibt dabei den Programmnamen, die Größe und den Dateityp auf dem Bildschirm aus.
Neben der Information über die korrekte Abspeicherung können Sie so also auch ein Inhaltsverzeichnis einer ganzen Kassette ausgeben lassen. Dies erfordert aber einiges an Geduld, da die Kassette dazu von Anfang bis Ende gelesen werden muß.
Die Anzeige der Programmtypen geschieht durch Sonderzeichen. "$" steht dabei für ein normales Programm, "%" für ein geschütztes Programm, "*" für eine Klartextdatei (ASCII-Datei) und "&" für eine binäre Datei.

1.1.2 Basic als Taschenrechner

Wenn der Computer etwas ausrechnen soll, brauchen Sie nur ein Fragezeichen, gefolgt von einem Leerzeichen und der Rechenaufgabe einzutippen und danach die Eingabetaste zu drücken. Das Ergebnis erscheint sofort auf dem Bildschirm.
Sie tippen ein:
? (23-7)*3
Der Computer antwortet mit: 48

Sie sehen, daß in Basic die normale mathematische Notation funktioniert. Ein paar Besonderheiten sollten Sie aber wissen:
- Als Multiplikationszeichen wird der Stern (*) verwendet. - Für Divisionen geben Sie den Schrägstrich (/) an. - Falls Sie keine Klammern angeben gilt "Punkt vor Strich".
Basic beherrscht die meisten mathematischen Funktionen, die auch auf einem besseren Taschenrechner zu finden sind. Dazu aber mehr im Kapitel "Arithmetik".

1.1.3 Befehlsübersicht des Direktmodus

Der einfachste Einstieg in den Umgang mit Basic ist der Befehlsmodus. Er ist bei fast jedem Homecomputer direkt nach dem Einschalten verfügbar. Sie tippen einen Befehl ein, drücken am Ende die Eingabetaste und schon wird der Befehl ausgeführt.
In der Praxis wird der Befehlsmodus hauptsächlich für zwei Aufgaben genutzt: Erstens können Programme vom Befehlsmodus aus von einem Speichergerät geladen bzw. auf einem Speichergerät abgelegt werden, zweitens ist der Befehlsmodus ein sehr schöner Taschenrechner.

CLEAR

CLEAR löscht alle Variablen.

WIDTH
WIDTH <zeichenprozeile>

Mit WIDTH legen Sie fest, wieviele Zeichen bei ihrem Drucker in einer Zeile Platz haben.

1.2 Programmieren

Der Befehlsmodus ist recht nützlich für einfache Rechenaufgaben - mit Basic-Programmierung hat seine Verwendung aber noch nichts zu tun.
Ein Programm ist eine Abfolge von Befehlen, die durch den Basicinterpreter abgearbeitet werden. Die Befehle stehen dabei in sogenannten Befehlszeilen, wobei jede Zeile normalerweise nur einen Befehl enthält. Die Reihenfolge, in der die Befehlszeilen abgearbeitet werden, wird durch Zeilennummern am Zeilenanfang bestimmt. Das Programm startet bei der kleinsten Zeilennummer und endet bei der größten. Die Nummern müssen nicht fortlaufend sein, es empfiehlt sich sogar, ein Programm zunächst z.B. in Zehnerschritten zu numerieren, um später Zeilen einfügen zu können.
Wenn Sie im Befehlsmodus eine Zeile mit einer Zeilennummer am Anfang eingeben, wird diese nicht sofort ausgeführt sondern gemäß ihrer Zeilennummer an der richtigen Stelle in das im Speicher befindliche Programm eingefügt. Ist der Speicher leer, wird das Programm mit der Eingabe der ersten Programmzeile angelegt.
Existiert bereits eine Zeile mit der Nummer der neu eingegebenen Zeile, so wird die alte kommentarlos durch die neue Zeile ersetzt. Die Eingabe einer Zeilennummer solo löscht eine bereits vorhandene Zeile mit dieser Nummer.
Für die Beispiele in diesem und den folgenden Kapiteln sollen drei einfache Basicbefehle schon an dieser Stelle vorgestellt werden. Sie werden in einem späteren Kapitel noch detailliert besprochen. Den ersten haben Sie schon kennengelernt: Das Fragezeichen im Direktmodus ist eigentlich die Abkürzung eines Basicbefehls, der ausgeschrieben "PRINT" heißt und für Bildschirmausgaben zuständig ist.
Eingaben des Benutzers kann ein Basicprogramm mit dem Befehl "INPUT" anfordern und der Befehl "LET" wird verwendet, um einer Variablen einen Wert zuzuweisen.
Am besten verstehen Sie diese drei Befehle anhand Ihres ersten Basicprogramms:
100 INPUT "GEBEN SIE EINE ZAHL EIN", A
110 LET B=A*A
120 PRINT "DAS QUADRAT VON "; A; " IST "; B

Die erste Zeile (Nummer 100) veranlasst den Computer, den Text "GEBEN SIE EINE ZAHL EIN" gefolgt von einem Fragezeichen und einem Eingabecursor auszugeben. Nun wartet der Computer auf die Eingabe einer Zahl. Diese wird dann in der Variablen "A" gespeichert.
In der zweiten Zeile (Nummer 110) wird einer neuen Variable "B" der Wert "A*A" zugewiesen. "B" enthält nun also den Wert von "A" im quadrat.
Die dritte Zeile schließlich gibt den Text "DAS QUADRAT VON ", den Wert der Variable "A", den Text " IST " und den Wert der Variable "B" nacheinander aus. Das Semikolon als Trennzeichen bewirkt, daß die Texte und Variableninhalte nahtlos aneinandergehängt werden.
Wenn Sie das Programm mit "RUN" ausführen, passiert auf dem Bildschirm zunächst folgendes:
GEBEN SIE EINE ZAHL EIN? _

Nun wartet der Computer auf Ihre Eingabe. Geben Sie nun z.B. eine 5 ein und drücken Sie dann die Eingabetaste. Folgendes steht nun auf dem Bildschirm:
GEBEN SIE EINE ZAHL EIN? 5
DAS QUADRAT VON 5 IST 25


1.3 Editieren eines Programms

Die Eingabe eines Programms in den CPC 464 ist einfach. Einfach eintippen und jede Zeile am Ende mit der Eingabetaste bestätigen. Solange sich der Cursor noch in einer Zeile befindet, kann diese komfortabel mit den Pfeiltasten links/rechts, der CLR- und der DEL-Taste bearbeitet werden. Dabei ist höchstens zu beachten, daß CLR die Funktion hat, die man normalerweise von DEL erwarten würde und DEL so funktioniert, wie bei anderen Computern die Backspace-Taste.
Komplizierter wird's, wenn man eine bereits abgeschickte Zeile nochmals bearbeiten will.
Ein Weg ist die EIngabe des Befehls EDIT, gefolgt von der Zeilennummer. Die zugehörige Zeile wird angezeigt und kann nun wie gewohnt bearbeitet werden.
Eine etwas kuriose, manchmal aber gar nicht so unpraktische Idee ist der Kopiercursor. Er kann mit den Pfeiltasten bei gedrückter SHIFT-Taste bewegt werden. Der normale Cursor bleibt dabei an seiner bisherigen Position. Nun kann durch Drücken der Taste COPY in der Mitte der Cursortasten das Zeichen unter dem Kopiercursor an die Position des normalen Cursors kopiert werden. Beide Cursoren bewegen sich dabei um ein Zeichen nach rechts, so daß durch mehrfaches Drücken der COPY-Taste ganze Zeilen schnell kopiert werden können. Die kopierte Zeile können Sie nun ganz normal bearbeiten.
Folgende Befehle im Direktmodus unterstützen Sie bei der Programmierung

EDIT
EDIT <Zeilennummer>

Wie bereits oben angeführt, können Sie mit dem EDIT-Kommando die bereits vorhandene Basiczeile mit der angegebenen Zeilennummer erneut bearbeiten.

DELETE
DELETE <startzeile>[-<endzeile>]

Der DELETE-Befehl löscht einzelne Zeilen oder einen ganzen Zeilenbereich. Ersteres macht nicht viel Sinn, da Sie diese Aufgabe schneller und einfacher durch die schlichte Eingabe der zu löschenden Zeilennummer gefolgt von der Eingabetaste lösen können.
Interessanter ist die Möglichkeit, ganze Programmteile zu löschen. Dazu geben Sie hinter DELETE die Zeilennummer der ersten zu löschenden Zeile gefolgt von einem Minuszeichen und der Zeilennummer der letzten zu löschenden Zeile an. Diese beiden Zeilen und alle dazwischenliegenden werden daraufhin gelöscht.
Um das gesamte Programm zu löschen ist der Befehl "NEW" bequemer anzuwenden.

AUTO
AUTO [<startzeile>][,<schrittweite>]

AUTO unterstützt Sie beim Schreiben von Programmen, indem Zeilennummern vorgegeben werden. Nachdem Sie den AUTO-Befehl abgesetzt haben, erscheint die unter <startzeile> angegebene Zeilennummer auf dem Bildschirm und Sie können die gewünschte Basiczeile dahinter schreiben. Sobald Sie die Eingabetaste drücken, erscheint in der folgenden Zeile sofort die nächste, um die angegebene <schrittweite> erhöhte Zeilennummer. Ist keine Schrittweite angegeben, erhöht AUTO die Zeilennummern immer um 10. Fehlt zudem die Startzeilennummer, beginnt die automatische Numerierung bei 10.
Eine Besonderheit ergibt sich, wenn AUTO eine Zeilennummer vorgibt, die bereits mit einer Programmzeile belegt ist. Dann erscheint hinter der Zeilennummer ein Stern als Hinweis.

RENUM
RENUM [<neu_von>],[<alt_von>],[<neu_schritt>]

RENUM numeriert ein Programm oder einen Teil davon neu durch. Dabei werden alle Verweise auf Zeilennummern im Programm (bei GOTO- oder THEN-Befehlen) automatisch an die neuen Nummern angepaßt.
Per Default ändert RENUMBER die erste Zeilennummer auf 10 und numeriert das Programm ab dieser in Zehnerschritten komplett neu durch. Sie können aber auch festlegen, ab welcher Programmzeile (<alt_von>) neu numeriert werden soll und zwar mit welcher Startzeilennummer (<neu_von>) und mit welcher Schrittweite.
Beachten müssen Sie dabei, daß der neu numerierte Bereich mit seinen Nummern noch zu den vorstehenden Zeilennummern paßt.
2. Programmstruktur

Im letzten Kapitel wurde ausgeführt, daß ein Programm immer in der Reihenfolge aufsteigender Zeilennummern ausgeführt wird. Das trifft aber nur für sehr einfache Programme zu, die z.B. beim Start ein paar Informationen abfragen und daraus irgendetwas berechnen.
Die meisten Programme erfordern jedoch ein deutlich komplexeres Verhalten. Oft muß ein Programm aufgrund vorgegebener Bedingungen unterschiedlich reagieren, d.h. verschiedene Programmteile abarbeiten. Dies wird als "bedingte Verzweigung" bezeichnet.
Eine andere Form der Strukturierung sind Schleifen, also die mehrfache Abarbeitung eines Programmteils bis zur Erfüllung einer Bedingung.
Eine letzte Variante bei den Strukturbefehlen ermöglicht die Nutzung von Unterprogrammen. Diese können dann jederzeit und von mehreren Stellen des Hauptprogramms aus aufgerufen werden.
Doch eins nach dem anderen:

2.1 Verzweigungen

Im folgenden wird immer wieder von Bedingungen die Rede sein. Sie sollten daher wissen, wie eine Bedingung aussieht. Basic verfügt für Bedingungen über ein großes Repertoir an Vergleichsoperatoren:
> größer < kleiner = gleich >= größer oder gleich <= kleiner oder gleich <> ungleich
Diese funktionieren nicht nur mit Zahlen sondern auch mit Zeichenketten, wobei hier "größer" gleichbedeutend ist mit "steht weiter hinten im Lexikon".
Mehrere Vergleiche können mit den logischen Operatoren "AND", "OR" und "NOT" verknüpft werden. Die Hierarchie der Vergleiche wird im Bedarfsfall mit Klammern festgelegt.
Am besten verstehen Sie die Möglichkeiten auch hier mit Hilfe einiger Beispiele:
A>=5
...ist wahr, wenn der Wert der Variable A größer oder gleich 5 ist.
"Klaus"<"Peter"
...ist wahr, weil "Klaus" lexikalisch vor "Peter" kommt
( A>=5 AND A<=10 ) OR B=1
...ist wahr, wenn A zwischen 5 und 10 liegt oder B gleich 1 ist.
GOTO / GO TO
GOTO <Zeilennummer>

Die einfachste Verzweigungsanweisung ist der GOTO-Befehl. Wenn die Programmabarbeitung auf einen GOTO-Befehl stößt, wird das Programm in der angegebenen Zeile fortgesetzt, ohne wenn und aber.
Bei gutem Programmierstil sollte der Einsatz des GOTO-Befehls auf den Ausgleich der Defizite bei anderen Strukturbefehlen in einfachen Basicdialekten beschränkt bleiben (siehe die Beispiele bei IF / THEN und ON GOTO). Wildes Herumspringen im Programm macht es sehr unübersichtlich - dem Basicinterpreter macht das nichts aus, aber der Autor des Programms wird sich nach ein paar Wochen in seinem eigenen Werk nicht mehr zurechtfinden.
GOTO kann alternativ auch GO TO geschrieben werden.

IF / THEN
IF <Bedingung> THEN <Zeilennummer>

Die bedingte Verzweigung IF / THEN führt einen Programmteil abhängig von einer Bedingung aus. Trifft die Bedingung zu, wird das Programm ab der hinter THEN angegebenen Zeilennummer fortgesetzt, andernfalls läuft das Programm in der nächsten Zeile (also ganz normal) weiter.
Das folgende Programm berechnet die Quadratwurzel der eingegeben Zahl. Ist die Zahl kleiner als Null, erscheint eine Warnung und das Programm ermöglicht einen neuen Versuch, eine Zahl einzugeben:
100 INPUT "GEBEN SIE EINE POSITIVE ZAHL EIN", A
110 IF A>=0 THEN 140
120 PRINT "DIE ZAHL "; A; "IST NEGATIV!"
130 GOTO 100
140 PRINT "DIE WURZEL VON "; A; " IST "; SQR( A )

ON / GOTO
ON <Ausdruck> GOTO <Zeilennummer>[, <Zeilennummer][...]

Mit ON / GOTO können Sie eine Mehrfachverzweigung realisieren. Der Ausdruck wird ausgewertet. Ist das Ergebnis gleich eins, wird zur ersten Zeilennummer der Liste hinter dem GOTO-Befehl gesprungen. Ist das Ergebnis zwei, erfolgt der Sprung zur zweiten der in der Liste aufgeführten Zeilennummern und so weiter.
Das folgende Beispiel zeigt ein einfaches Menü. Sie treffen Ihre Auswahl durch Eingabe einer Nummer:
100 PRINT "WAS MÖCHTEN SIE BESTELLEN?"
110 PRINT "1. ETWAS ZU TRINKEN"
120 PRINT "2. EIN HAUPTGERICHT"
130 PRINT "3. EINEN NACHTISCH"
140 INPUT "GEBEN SIE EINE NUMMER EIN", A
150 ON A GOTO 200, 300, 400
200 PRINT "SIE BEKOMMEN EINE HALBE BIER"
210 GOTO 500
300 PRINT "SIE BEKOMMEN EINE SCHWEINSHAXE MIT SAUERKRAUT"
310 GOTO 500
400 PRINT "SIE BEKOMMEN NOCH EINE HALBE BIER"
500 PRINT "WOHL BEKOMM'S"


2.2 Schleifen


FOR / TO / NEXT
FOR <Variable>=<Ausdruck> TO <Ausdruck> [STEP <Ausdruck>]
...
NEXT <Variable>

Bei einer Schleife werden ein oder mehrere Befehle mehrfach ausgeführt. Diese Befehlsgruppe wird eingerahmt durch einen Schleifenbefehl am Anfang und einen am Ende. Bei der FOR/NEXT-Schleife handelt es sich um eine Zählschleife, d.h. bereits der Schleifenbefehl am Anfang legt die Zahl der Schleifendurchläufe fest. Dazu wird einer Variablen das Ergebnis eines Ausdrucks zugewiesen. Diese Variable wird dann mit jedem Durchlauf der Schleife um den hinter "STEP" angegeben Wert erhöht. Fehlt die Angabe von "STEP", wird um eins erhöht.
Die Schleife endet mit dem Erreichen des Wertes, der hinter "TO" angegeben ist.
Zwei Beispiele:
1. Der Computer soll die 7er-Reihe aufsagen:
100 FOR I=7 to 70 STEP 7
110 PRINT I
120 NEXT I

In der ersten Zeile wird der Variablen "I" zunächst der Wert 7 zugewiesen. Dieser wird in der zweiten Zeile dann auf dem Bildschirm ausgegeben. Die dritte Zeile veranlasst, daß "I" um die Schrittweite 7 erhöht wird und prüft, ob der Endwert 70 bereits erreicht ist. Da dem nicht so ist, wird die Schleife erneut durchlaufen und so der neue Wert von "I", also 14, ausgegeben. Das wird nun so fortgesetzt, bis "I" nach der Erhöhung um 7 den Wert 77 annimmt. Der Endwert 70 ist nun überschritten und die Schleife endet.
2. Der Computer soll das gesamte kleine Einmaleins anzeigen:
100 FOR A=1 TO 10
110 FOR B=1 TO 10
120 PRINT A*B;
130 NEXT B
140 PRINT
150 NEXT A

Jetzt wird klar, warum beim NEXT-Befehl nochmal der Variablenname steht: Er macht klar, welcher NEXT-Befehl zu welchem FOR-Befehl gehört.
Das Programm beginnt in Zeile 100 mit der Zuweisung des Werts 1 an die Variable "A". In Zeile 110 erhält "B" ebenfalls den Wert 1. Zeile 120 gibt nun den Wert von 1*1 auf dem Bildschirm aus. Das Semikolon am Zeilenende bewirkt, daß die nächste Ausgabe mit PRINT in der gleichen Zeile angehängt wird. In der folgenden Zeile (130) wird nun "B" um eins erhöht, mit dem Endwert 10 verglichen und das Programm in Zeile 120 fortgesetzt. Nun erscheint das Ergebnis von 1*2 auf dem Bildschirm. Dies wiederholt sich nun solange, bis die Schleife mit einem Wert von 10 in der Variable "B" durchlaufen wurde. Nun ist der Endwert erreicht und das Programm geht mit Zeile 140 weiter. Diese macht keine Ausgabe, sondern veranlaßt, daß der nächste PRINT-Befehl seine Ausgabe in einer neuen Bildschirmzeile beginnt. Nun wird in Zeile 150 der Wert von "A" um eins erhöht, mit dem Endwert für "A" verglichen und das Programm in Zeile 110 fortgesetzt. Dort erhält "B" wieder den Wert 1 und die innere Schleife (Zeilen 110 - 130) läuft wieder von 1 bis 10 und gibt dabei die Zeierreihe auf dem Bildschirm aus. Das Spiel wiederholt sich solange, bis auch "A" den Endwert erreicht hat und das geamte kleine Einmaleins auf dem Bildschirm steht.

WHILE / WEND
WHILE <bedingung>
...
WEND

WHILE / WEND erzeugt eine abweisende Schleife, d.h. bereits vor dem ersten Durchlauf wird bereits die Bedingung geprüft und bei Nichterfüllung die gesamte Schleife übersprungen. Andernfalls läuft die Schleife solange ab, wie die Bedingung noch erfüllt ist.

2.3 Unterprogramme


GOSUB / RETURN
GOSUB <Zeilennummer>
RETURN

Der Befehl "GOSUB" springt zunächst genauso wie "GOTO" einfach zu der angegebenen Zeilennummer und setzt das Programm dort fort. Der Basicinterpreter merkt sich aber, welche Zeile auf die mit dem GOSUB-Befehl folgt. Falls das Programm nun auf einen "RETURN"-Befehl stößt, wird die Programmausführung in der gemerkten Zeile fortgesetzt.
Als Beispiel soll ein Unterprogramm dienen, das einen Text nacheinander zeichenweise auf den Bildschirm schreibt. Machen Sie sich nichts daraus, wenn Sie die folgenden Zeilen noch nicht ganz verstehen - es genügt für's erste zu wissen, daß sie den Inhalt der Stringvariablen "A$" zeichenweise auf den Bildschirm schreiben. Eine Stringvariable ist eine Variable, die Text enthalten kann.
1000 FOR I=1 TO LEN(A$)
1010 PRINT MID$(A$,I,1);
1020 NEXT I
1030 RETURN

Dieses Unterprogramm für sich auszuführen macht keinen Sinn: Erstens hat A$ noch keinen Inhalt, es wird also auch nichts auf den Bildschirm geschrieben. Zweitens würde der Basicinterpreter in Zeile 1030 auf den RETURN-Befehl stoßen, ohne daß er zuvor bei einem GOSUB vorbeigekommen wäre. Das Programm würde daher mit einer Fehlermeldung abbrechen.
Wir benötigen daher noch ein Hauptprogramm, das unser Unterprogramm nutzt. Es kann es nicht nur einmal, sondern beliebig oft und von verschiedenen Stellen aus aufrufen:
100 A$="ACHTUNG! ACHTUNG! HIER SPRICHT DEIN COMPUTER!"
110 GOSUB 1000
120 PRINT
130 A$="IN MEINEM SPEICHER HAT SICH EIN BIT VERKLEMMT."
140 GOSUB 1000
150 PRINT
160 A$="BITTE DREH MICH UM UND KLOPF MIR AUF DEN RUECKEN!"
170 GOSUB 1000
180 PRINT
190 END

Zeile 190 enthält einen weiteren neuen Befehl: END. Er führt dazu, daß das Programm an dieser Stelle beendet wird. Es gilt als ordentlicher Programmierstil, alle Unterprogramme am Ende des Programmes (d.h. bei den hohen Zeilennummern) unterzubringen. Das davorstehende Hauptprogramm endet dann mit dem END-Befehl, andernfalls wird zuletzt das erste Unterprogramm nach dem Hauptprogramm ausgeführt und der Basicinterpreter scheitert am RETURN-Befehl, der dieses Unterprogramm abschließt.

ON / GOSUB / RETURN
ON <Ausdruck> GOSUB <Zeilennummer>[, <Zeilennummer>][...]
...
RETURN

ON / GOSUB funktioniert genauso wie ON / GOTO, allerdings wird nicht einfach zu eine der in der Liste angegebenen Zeilennummern gesprungen, sondern an der angesprungenen Zeilennummer wird ein Unterprogramm erwartet, das dann irgendwann mit "RETURN" zu der auf den ON/GOTO-Befehl folgenden Zeile zurückkehrt.

2.4 Programmsteuerung


STOP

STOP beendet die Programmausführung. Der Unterschied zum END-Befehl besteht darin, daß ein per STOP beendetes Programm durch Eingabe von CONT im Direktmodus in der Folgezeile fortgesetzt werden kann und daß beim Abbruch die Bildschirmmeldung "BREAK IN <zeilennummer>" erscheint.
Somit sollte die Anwendung des STOP-Befehls auf die Fehlersuche und den Test von Programmen beschränkt bleiben.
Die Vorgehensweise ist dabei ganz einfach: In jenem Programmteil, das den Fehler mutmaßlich verursacht streuen Sie an geeigneten Stellen STOP-Befehle ein. Immer wenn das Programm nun abbricht, können Sie im Direktmodus Variablenwerte abfragen und so prüfen, ob alle Variablen die erwarteten Inhalte haben. Wenn ja, setzen Sie das Programm bis zur nächsten STOP-Stelle fort (mit CONT). Wenn nein, wird sich der Fehler wahrscheinlich zwischen dem aktuellen und dem vorhergehenden STOP-Befehl eingeschlichen haben.
3. Arithmetik und Variablen

3.1 Variablen

In den letzten Kapiteln war schon mehrfach von Variablen die Rede. Nun wollen wir sie etwas genauer betrachten.
Sie kennen Variablen aus der Mathematik als Platzhalter für Zahlen. Man kann mit Variablen ausdrücken, daß eine Formel gilt - unabhängig welche Zahlen man für die darin enthaltenen Variablen einsetzt.
In allen gängigen Programmiersprachen erfüllen Variablen die gleiche Funktion: Sie können stellvertretend für Zahlen angegeben werden. Man kann einer Variablen einen Wert zuweisen. Überall, wo diese Variable dann im Programm vorkommt, wird sie dann so behandelt als stünde da direkt der Wert dieser Variablen.

LET
[LET] <Variablenname>=<Ausdruck>

Mit dem LET-Befehl gibt man einer Variablen einen Wert. Hatte diese Variable zuvor bereits einen anderen Wert, so wird dieser überschrieben. Der LET-Befehl kann auch weggelassen werden.
A=5
weist also der Variablen A den Wert 5 zu.
Das folgende Beispiel berechnet mit Hilfe der Formel des Pythagoras die Länge der langen Seite (Hypotenuse) eines rechtwinkligen Dreiecks:
100 INPUT "LAENGE DER 1. KATHETE:", A
110 INPUT "LAENGE DER 2. KATHETE:", B
120 C = SQR( A*A + B*B )
130 PRINT "LAENGE DER HYPOTENUSE: "; C


3.2 Rechnen mit Zahlen

Ein Computer wäre kein Computer, könnte er nicht rechnen. Bisher haben Sie in den Programmbeispielen fast nur die Grundrechenarten sehen können. Basic kann aber noch mehr:

Operatoren

Als Operatoren bezeichnet man die normalen mathematischen Rechenzeichen. Neben den bereits vorgestellten "+" (Addition), "-" (Subtraktion), "*" (Multiplikation) und "/" (Division) kennt Basic noch Klammern zur Festlegung der Auswertungsreihenfolge eines Ausdrucks und das "^" als Exponentzeichen.
2*(4+1) ergibt 10
3^2 ergibt 9
5/2 ergibt 2.5

Am Ergebnis des letzten Beispiels sehen Sie, daß Basic auch mit nichtganzen Zahlen umgehen kann. Entgegen der in Deutschland gebräuchlichen Notation wird in Basic jedoch statt dem Komma ein Punkt verwendet.

DEFINT, DEFREAL
DEFINT <buchstabe>[,<buchstabe>][-<buchstabe>]...
DEFREAL <buchstabe>[,<buchstabe>][-<buchstabe>]...

Locomotive Basic ermöglicht die Definition von Variablen vom Typ Fließkomma und Ganzzahl abhängig vom ersten Buchstaben des Variablennamens.
Der Befehl
DEFINT A-C
definiert alle Variablen, deren Namen mit A, B oder C beginnt als Ganzzahlvariablen.
Ganzzahlvariablen können zwar nur ganze Zahlen von -32768 und 32767 annehmen, dafür arbeitet der Basicinterpreter mit ganzen Zahlen wesentlich schneller.

INT()

INT() rundet auf die nächste ganze Zahl ab.
INT( 5.32 ) ergibt 5
INT( -2.3 ) ergibt -3


ABS()

ABS() bildet den Betrag.
ABS( 23 ) ergibt 23
ABS( -4 ) ergibt 4


SIN(), COS(), TAN()

SIN() errechnet den Sinus. Das Argument wird im Bogenmaß erwartet. Das gleiche gilt für den Cosinus COS() und den Tangens TAN().
SIN( 3.1415 / 2 ) ergibt 1


SGN()

SGN() liefert 1 bei positivem Argument, -1 bei negativem Argument und 0, falls das Argument gleich Null ist.
SGN( 0.3 ) ergibt 1
SGN( -1423 ) ergibt -1


SQR()

SQR() errechnet die Quadratwurzel.
SQR( 16 ) ergibt 4


LN(), EXP()

LN() bestimmt den natürlichen Logarithmus, EXP() die Exponentialfunktion (d.h. die Eulersche Zahl hoch dem Argument).
LN( 1 ) ergibt 0
EXP( 1 ) ergibt 2.7172...


DEF FN, FN
DEF FN<name>(<parameter>)=<ausdruck>
FN(<ausdruck>)

Sie können nicht nur mit den vorgefertigten Basicfunktionen arbeiten. Wenn eine Formel in einem Programm mehrfach benötigt wird, kann es nützlich sein, sie als Funktion zu definieren. Im Gegensatz zu anderen Programmiersprachen ist die Funktionsdefinition in Basic sehr eingeschrängt, sie darf nämlich nur eine einfache Formel enthalten. Programmierer höherer Programmiersprachen kennen Funktionen hingegen als Unterprogramme mit Rückgabewert.
Als Beispiel sei hier eine Sinusfunktion aufgeführt, deren Argument statt im Bogenmaß in Grad angegeben werden kann:
DEF FNSING(x)=SIN(x/PI*180)

Nun können Sie die neue Funktion mit vorangestelltem "FN" genauso nutzen, wie jede vorgefertigte Basicfunktion auch:
FNSING(90) ergibt 1
FNSING(270) ergibt -1


DEG

Der Befehl DEG schaltet die Berechnung von SIN() und COS() auf's Gradmaß um.

RAD

RAD schaltet die Berechnung von SIN und COS wieder ins Bogenmaß zurück.

ATN()

Berechnet den Arkustankens. Das Ergebnis ist im Bogenmaß

LOG10()

Berechnet den Zehnerlogarithmus

MAX(), MIN()
MAX( <zahl>[,<zahl>][...])
MIN( <zahl>[,<zahl>][...])

MAX ermittelt den Maximalwert unter allen angegebenen Zahlen, MIN den Minimalwert.

CINT()

Rundet die angegebene Zahl und liefert einen Ganzzahlwert zurück, der im Bereich von -32768 bis 32767 liegen muß.

FIX()

Schneidet bei der angegebenen Zahl den Nachkommaanteil ab und übergibt das Ergebnis als ganze Zahl zwischen -32768 und 32767.

ROUND()
ROUND( <ausdruck>[,<anzahl nachkommastellen> )

Rundet das Ergebnis des Ausdrucks auf die angegebene Anzahl Nachkommastellen oder per Default auf eine ganze Zahl.

CREAL()

Wandelt die angegebene Ganzzahl in eine Fließkommazahl um.

UNT()

Wandelt die postive angegebene Ganzzahl in eine vorzeichenbehaftete 16-Bit-Zahl zwischen -32768 und 32767.

RND()
RND(<Basiswert>)

RND() liefert Pseudozufallszahlen, die größer oder gleich Null und kleiner als eins sind. "Pseudo" deshalb, weil die Zahlen nicht ganz zufällig sind: Ist der Basiswert < 0, wird die Zufallszahl aus dem Basiswert berechnet - der gleiche Basiswert liefert also immer die gleiche Zufallszahl. Noch weniger einfallsreich zeigt sich RND(0): Hier ergibt sich immer die zuletzt ermittelte Zufallszahl als Ergebnis.
Am tauglichsten erscheint RND() bei positiven Basiswerten. Aber auch hier wird eine Zufallszahl immer aus der vorhergehenden berechnet und - was noch schwerer wiegt: Nach jedem Neustart des Basicinterpreters produziert RND wieder die exakt gleichen Zufallszahlen.
Glücklicherweise gibt es Abhilfe:

RANDOMIZE

RANDOMIZE initialisiert den Zufallszahlengenerator mit einem wirklich zufälligen Wert. Dadurch sind die Ergebnisse nachfolgender RND()-Aufrufe mit positivem Basiswert nicht mehr vorhersehbar. Ein Programm, das mit echten Zufallszahlen arbeiten möchte, sollte daher ganz am Anfang einmal einen Aufruf von RANDOMIZE enthalten.

FRE()

Die FRE-Funktion ermittelt den aktuell freien Arbeitsspeicher des Rechners. Das Argument wird dabei nicht ausgewertet, normalerweise gibt man daher FRE(0) an. Die Funktion wird wohl am häufigsten im Direktmodus verwendet:
? FRE(0)

Dabei ist zu beachten, daß FRE eine Vorzeichenbehaftete 16-Bit-Zahl ausgibt. Liegt der freie Arbeitsspeicher demzufolge über 32767, liefert FRE(0) ein negatives Ergebnis! Das korrekte Ergebnis erhält man in diesem Fall durch Addition von 65536.

PI

PI ist als Konstante fest definiert. Sie können daher PI wie eine Variable in Ausdrücken verwenden. Einen anderen Wert können Sie allerdings nicht dafür definieren.
100 INPUT "RADIUS : ", R
110 PRINT "UMFANG : U="; R*2*PI
120 PRINT "FLAECHE: A="; R^2*PI


TIME

TIME ist eine Systemvariable, die die seit dem Rechnerstart vergangene Zeit in Einheiten von dreihundertstel Sekunden enthält. Bei Schreib- und Lesezugriffen auf das Band bleibt TIME stehen.

3.3 Strings

Strings sind Zeichenketten, d.h. eine Abfolge von Buchstaben, Zahlen oder Sonderzeichen. Es gibt spezielle Variablen, die anstelle von Zahlen Strings als Wert annehmen können. Diese werden als Stringvariablen bezeichnet und durch ein Dollarzeichen am Ende des Variablennamens kenntlich gemacht.
Mit Strings kan man natürlich nicht im herkömmlichen Sinne rechnen. Zumindest die Addition ist jedoch definiert. Sie hängt die "Summanden" einfach aneinander.
A$="DIES IST "
B$="EIN BEISPIEL"
C$=A$+B$
PRINT C$

Der PRINT-Befehl schreibt den Wert der Stringvariablen C$ auf den Bildschirm. Es erscheint
DIES IST EIN BEISPIEL


DEFSTR
DEFSTR <buchstabe>[,<buchstabe>][-<buchstabe>]...

Genau wie bei den Befehlen DEFINT oder DEFREAL legt DEFSTR für alle Variablen, deren Name mit einem der angegebenen Buchstaben beginnt fest, daß sie nur Zeichenketten (Strings) annehmen können.
Verschiedene Funktionen ermöglichen sehr interessante Anwendungen von Strings:

LEN()

LEN() ermittelt die Länge eines Strings
LEN( "HALLO" ) ergibt 5


LEFT$(), RIGHT$(), MID$()
LEFT$( <string>, <anzahl zeichen> )
RIGHT$( <string>, <anzahl zeichen> )
MID$( <string>, <ab zeichen nr>, <anzahl zeichen> )

Mit diesen Funktionen können Sie Teile von Strings ermitteln. LEFT$ liefert die angegebene Anzahl Zeichen vom Anfang des Strings, RIGHT$ ebenso aber vom Ende des Strings und mit MID$ können Sie die angegebene Anzahl von Zeichen ab einer bestimmten Position im String ausschneiden
LEFT$( "DONAUDAMPFSCHIFF", 5 ) ergibt DONAU
RIGHT$( "DONAUDAMPFSCHIFF", 6 ) ergibt SCHIFF
MID$( "DONAUDAMPFSCHIFF", 6, 5 ) ergibt DAMPF


ASC()

Jeder Buchstabe, jede Ziffer und jedes Sonderzeichen wird vom Computer intern als Zahl gespeichert. Welches Zeichen dabei welcher Zahl entspricht, ist in einem Code festgelegt. Etwa die Hälfte dieses Codes ist standardisiert und auf jedem Computer gleich. Dieser Code heißt "ASCII" (american standard code for information interchange).
Mit der ASC()-Funktion können Sie die Zahl ermitteln, die dem ersten Zeichen des angegebenen Strings zugeordnet ist.
ASC( "A" ) ergibt 65


CHR$()

Die umgekehrte Funktion zu ASC() stellt CHR$() dar. Die angegebene Zahl wird in das zugehörige Zeichen nach dem ASCII-Code umgewandelt.
CHR$( 65 ) ergibt 65

So können Sie sehr einfach ein Programm schreiben, das eine ASCII-Codetabelle auf den Bildschirm schreibt:
100 FOR I=0 TO 255 STEP 4
110 FOR J=0 TO 3
120 PRINT I+J; ":"; CHR$( I+J ); " ";
130 NEXT J
140 PRINT
150 NEXT I


VAL, STR$

VAL wandelt einen Zahlenstring in eine Zahl, STR$ tut genau das Gegenteil. Stößt VAL bei der Umwandlung des Strings auf ein Zeichen, das nicht zu einem Zahlenstring paßt, bricht die Wandlung ab.
Auch hier wird die Wirkungsweise wohl am ehesten durch einige Beispiele klar:
VAL( "12" ) ergibt die Zahl 12
VAL( "35.6" ) ergibt die Zahl 35,6
VAL( "23.07.1998" ) ergibt die Zahl 23,07 (eine Zahl kann nur ein Komma
enthalten) VAL( "7A12" ) ergibt die Zahl 7 (der Rest läßt sich nicht als Zahl lesen)

STR$( 14.5 ) ergibt den String "14.5"
STR$( 64 ) ergibt den String "64"



INSTR
INSTR( [<offset>,]<string1>, <string2> )

Sucht <string2> in <string1>, wobei die ersten <offset> Zeichen in String1 übersprungen werden. Ist ersterer vollständig enthalten, gibt die Funktion INSTR die Position zurück, ab der <string2> in <string1> enthalten ist. Andernfalls liefert INSTR als Ergebnis die Null.
INSTR( "SCHIFF", "DONAUDAMPFSCHIFFFAHRT" ) ergibt 11
INSTR( "c", "abcdefg" ) ergibt 3
INSTR( "a", "bcdefgh" ) ergibt 0


STRING$
STRING$( <anzahl>, <string> )

STRING$ hängt den angegebenen String <anzahl> Mal hintereinander und gibt das Ergebnis zurück.
STRING$( 32, "-" ) ergibt eine Linie aus 32 Minuszeichen
STRING$( 3, "Bla " ) ergibt "Bla Bla Bla "


BIN$
BIN$( <ausdruck>[,<stellenzahl>] )

Der Ausdruck wird ausgewertet und das Ergebnis in eine Binärzahl gewandelt. Diese liefert BIN$ dann als String. Sie können die gewünschte Stellenzahl der zu erzeugenden Binärzahl vorgeben. Ist das Ergebnis kürzer, wird es mit führenden Nullen auf die gewünschte Länge gebracht.

HEX$
HEX$( <ausdruck>[,<stellenzahl>] )

Der Ausdruck wird ausgewertet und das Ergebnis in eine Hexadezimalzahl gewandelt. Diese liefert HEX$ dann als String. Sie können die gewünschte Stellenzahl der zu erzeugenden Hexadezimalzahl vorgeben. Ist das Ergebnis kürzer, wird es mit führenden Nullen auf die gewünschte Länge gebracht.

LOWER$(), UPPER$()

Wandelt alle Zeichen des angegebenen Strings in Klein- bzw. Großbuchstaben.

SPACE$()

Erzeugt eine Zeichenkette, die aus der angegebenen Anzahl Leerzeichen besteht.

3.4 Felder

Oft ist es notwendig, viele gleichartige Informationen in Variablen abzulegen. Der einfachste Weg, dies zu tun ist die Verwendung von Feldvariablen. Einem Variablennamen kann dabei eine vorher festzulegende Anzahl verschiedener Werte zugewiesen werden. Dem Variablennamen wird dabei in eckigen Klammern ein Index mitgegeben, der die verschiedenen möglichen Werte mit Nummern versieht.

DIM
DIM <Variablenname>[<Anzahl Feldelemente>]

Wie gesagt, die Anzahl möglicher verschiedener Werte in einer Feldvariable muß zuvor festgelegt werden. Dazu dient der DIM-Befehl. Er muß im Programm ausgeführt werden, bevor die zugehörige Feldvariable erstmals benutzt wird.
100 DIM U[12]
110 FOR I=1 TO 12
120 PRINT "UMSATZ IM "; I; ". MONAT DES JAHRES:";
130 INPUT U[I]
140 NEXT I
150 FOR I=1 TO 12
160 PRINT I,
170 FOR J=1 TO U[I]
180 PRINT "#";
190 NEXT J
200 PRINT
210 NEXT I

Das Beispielprogramm definiert in Zeile 100 eine Feldvariable mit 12 Elementen. In den Zeilen 110 bis 140 werden diese dann vom Anwender des Programms mit Werten gefüllt. Der Rest des Programms gibt die eingegebenen Werte dann als Balkendiagramm wieder aus.

ERASE
ERASE <feldname>[,<feldname>...]

ERASE löscht eine Felddefinition und gibt den dadurch belegten Arbeitsspeicher wieder frei.

3.5 Programminterne Daten

Oftmals werden in einem Programm Daten benötigt, die fest hinterlegt sein sollen, d.h. nicht jedes mal von Neuem abgefragt werden sollen. Basic bietet dafür einen einzigartigen Mechanismus: Beliebige Daten können, durch Komma getrennt, in sogenannten DATA-Zeilen abgelegt werden. Diese können an jeder beliebigen Stelle im Programm stehen. Stößt der Basicinterpreter bei der Programmabarbeitung auf eine DATA-Zeile, so wird diese ignoriert. Üblicherweise stellt man DATA-Zeilen jedoch ans Programmende.
Der Zugriff auf DATA-Zeilen erfolgt durch den READ-Befehl. Dieser ist in der Verwendung stark an den INPUT-Befehl angelehnt. Die Informationen werden jedoch nicht von der Tastatur eingelesen, sondern von vorn nach hinten aus den im Programm vorhandenen DATA-Zeilen. Dieser Vorgang bleibt im Gegensatz zum Einlesen von Daten per INPUT-Befehl auf dem Bildschirm unsichtbar.
Sollen Daten mehrfach gelesen oder selektiv auf bestimmte Datenbereiche zugegriffen werden, so können Sie per RESTORE-Befehl festlegen, ab welcher DATA-Zeilennummer folgende READ-Befehle ihre Daten lesen sollen.
Nochmals im Detail:

DATA
DATA <konstante>[,<konstante>][...]

Hinter dem Data-Befehl folgen eine oder mehrere Konstanten, wobei es sich dabei um Zahlen oder Zeichenketten handeln darf. Die Trennung erfolgt durch Kommas, Zeichenketten sollten in Anführungszeichen eingeschlossen werden.

READ
READ <variablenname>[,<variablenname>][...]

Die nächste Konstante oder (bei mehreren angegebenen Variablennamen) die nächsten Konstanten aus den DATA-Zeilen werden gelesen und als Wert(e) der/den angegebenen Variablen zugewiesen.
Ein Beispiel dürfte die Verwendung von Read und Data etwas anschaulicher machen. Es handelt sich dabei um eine abgewandelte Fassung des Balkendiagramm-Generators aus der Erklärung des DIM-Befehls:
100 DIM U[12]
110 FOR I=1 TO 12
130 READ U[I]
140 NEXT I
150 FOR I=1 TO 12
160 PRINT I,
170 FOR J=1 TO U[I]
180 PRINT "#";
190 NEXT J
200 PRINT
210 NEXT I
1000 DATA 5, 8, 9, 13, 12, 18, 20, 17, 11, 8, 1, 0


RESTORE
RESTORE [zeilennummer]

Als nächste per READ zu bearbeitende DATA-Zeile wird die mit der angegebenen Zeilennummer (oder die erste darauffolgende DATA-Zeile, falls die angegebene Zeilennummer keine DATA-Zeile enthält) festgelegt. Wird keine Zeilennummer angegeben, liest der nächste READ-Befehl wieder ab der ersten DATA-Zeile des Programms.
Zur Illustration soll hier nochmals eine Variante des Balkendiagramms dienen:
100 DIM U[12]
101 PRINT "DIE UMSATZZAHLEN DER FOLGENDEN JAHRE LIEGEN VOR:"
102 PRINT "[0] 1996, [1] 1997, [2] 1998"
103 INPUT "GEBEN SIE 0, 1 ODER 2 EIN:"; A
104 RESTORE 1000+A
105 READ J
106 PRINT "UMSATZZAHLEN DES JAHRES "; J; ":"
110 FOR I=1 TO 12
130 READ U[I]
140 NEXT I
150 FOR I=1 TO 12
160 PRINT I,
170 FOR J=1 TO U[I]
180 PRINT "#";
190 NEXT J
200 PRINT
210 NEXT I
1000 DATA 1996, 5, 8, 9, 13, 12, 18, 20, 17, 11, 8, 1, 0
1001 DATA 1997, 3, 7, 11, 17, 12, 16, 21, 22, 18, 11, 10, 9
1002 DATA 1998, 15, 18, 20, 22, 23, 21, 20, 17, 18, 16, 16, 15