Programmieren in Basic

Basic ist eine sehr simple, dafür aber auch leicht erlernbare Programmiersprache. Im Gegensatz zu vielen  moderneren Sprachen ist Basic eine Interpretersprache. Das heißt, daß ein Programm, ein Programmteil oder auch nur ein einzelner Befehl jederzeit ausprobiert werden kann. Das Ergebnis kann sofort begutachtet werden. Basic ist in dieser Hinsicht vergleichbar mit modernen Skriptsprachen wie PHP oder Perl.

Man kann Basic schon nach wenigen Minuten als Taschenrechner einsetzen, während andere Sprachen zuerst eine aufwendige Einarbeitung in Editor, Compiler und Entwicklungsumgebung voraussetzen.
Dadurch ist die Abarbeitungsgeschwindigkeit fertiger Basicprogramme aber auch nicht mit der von C- oder gar Assemblerprogrammen vergleichbar.

Eine Besonderheit von Basic ist, dass es bei vielen damit ausgestatteten Computern gleichzeitig auch die Schnittstelle zum Betriebssystem ist. Wenn man den Computer einschaltet, landet man sofort im Basic-Interpreter und könnte auf der Stelle damit loslegen, ein Programm zu schreiben. Um ein bereits fertiges Programm zu nutzen, musste man es in den Arbeitsspeicher holen. Das erledigt normalerweise der Basic-Befehl "LOAD", gefolgt von "RUN" um das Programm zu starten. Viele Computerbesitzer kannten nur diese beiden Befehle, weil sie ausschließlich mit fertiger Software umgingen. Im Freundeskreis nannten wir damals solche Menschen scherzhaft "Loadrunner".

Eher unerfreulich war die Tatsache, dass es leider keinen verbindlichen Standard für Basic gab. Fast jeder Hersteller dachte sich eigene Befehle aus, um den Grundwortschatz von Basic zu erweitern. So gibt es oft für die gleiche Aufgabe bei jedem Computersystem einen anderen Befehl. Und selbst an den wenigen einheitlichen Befehlen manipulierten viele Firmen herum, so dass auch hier Programme nicht einfach ausgetauscht werden konnten. Trotzdem gibt es eine Art Minimal-Basic, dessen Befehle überwiegend gleich implementiert sind. Wenn man diese beherrscht, kann man die meisten Basic-Computer zumindest ausprobieren. Die erweiterten Befehle kann man dann ja immer noch in der Anleitung nachlesen.

1.1 Befehlsmodus

Der einfachste Einstieg in den Umgang mit Basic ist der Befehlsmodus. Er ist bei fast jedem Homecomputer direkt nach dem Einschalten verfügbar. Sie tippen einen Befehl ein, drücken am Ende die Eingabetaste und schon wird der Befehl ausgeführt. In der Praxis wird der Befehlsmodus hauptsächlich für zwei Aufgaben genutzt: Erstens können Programme vom Befehlsmodus aus von einem Speichergerät geladen bzw. auf einem Speichergerät abgelegt werden, zweitens ist der Befehlsmodus ein sehr schöner Taschenrechner.

1.1.1 Basic als Taschenrechner

Wenn der Computer etwas ausrechnen soll, brauchen Sie nur ein Fragezeichen, gefolgt von einem Leerzeichen und der Rechenaufgabe einzutippen und danach die Eingabetaste zu drücken. Das Ergebnis erscheint sofort auf dem Bildschirm.
Sie tippen ein:

? (23-7)*3 

Der Computer antwortet mit: 48

Sie sehen, daß in Basic die normale mathematische Notation funktioniert. Ein paar Besonderheiten sollten Sie aber wissen:

• Als Multiplikationszeichen wird der Stern (*) verwendet.
• Für Divisionen geben Sie den Schrägstrich (/) an.
• Falls Sie keine Klammern angeben gilt "Punkt vor Strich".

Basic beherrscht die meisten mathematischen Funktionen, die auch auf einem besseren Taschenrechner zu finden sind. Dazu aber mehr im Kapitel "Arithmetik".

1.1.2 Befehle im Direktmodus

 LOAD ["<Programmname>"] 

Load lädt das angegebene Programm von der Datenkassette in den Arbeitsspeicher. Wird der Programmname weggelassen, nimmt der Basicinterpreter das erstbeste Programm auf der Kassette.

Leider gehört der Load-Befehl zu den hochgradig systemspezifischen Befehlen. Es gibt Erweiterungen, um beim Laden ein bestimmtes Laufwerk anzusteuern, bestimmte Dateitypen zu laden und anderes. Bei Diskettenlaufwerken ist es eine essenzielle Funktion, das Inhaltsverzeichnis auflisten zu lassen. Dafür gibt es leider gar keinen standardisierten Basic-Befehl.

 SAVE "<Programmname>" 

Das im Arbeitsspeicher befindliche Programm wird auf Datenkassette unter dem angegebenen Namen gespeichert.

 RUN ["<Programmname>"|<Zeilennummer>] 

RUN alleine führt das im Arbeitsspeicher befindliche Programm ab dem Programmanfang aus. Wird ein Programmname angegeben, sucht der Basicinterpreter dieses Programm auf der Datenkassette, lädt und startet es. RUN kann ein Programm aber auch ab einer bestimmten Stelle ausführen. Dazu geben Sie einfach die erste abzuarbeitende Zeilennummer an. (Was es mit den Zeilennummern auf sich hat, erfahren Sie im nächsten Kapitel.)

 LIST [<Zeilennummer>][-[<Zeilennummer]] 

Um das Programm im Arbeitsspeicher oder einen Teil davon zu betrachten, benötigen Sie den LIST-Befehl. Für sich alleine zeigt er das ganze Programm an. Es kann aber auch eine einzelne Zeilennummer, ein Zeilennummernbereich (<von>-<bis>) oder alles bis zu einer bestimmten Zeilennummer (-<bis>) oder alles ab einer bestimmten Zeilennummer (<von>-) angezeigt werden.
Der Befehl LIST 240-
zeigt also alle Befehlszeilen ab 240 bis zum Programmende an. Wenn Sie noch nicht wissen, was eine Zeilennummer ist - keine Bange, im nächsten Kapitel erfahren Sie's.

 NEW 

NEW löscht das im Arbeitsspeicher befindliche Programm. Anschließend steht also wieder der gesamte Hauptspeicher zur Verfügung.

 CONT 

Mit CONT können Sie ein abgebrochenes Programm fortsetzen.

 REM <Kommentartext> 

REM leitet einen Kommentartext ein. Eine Zeile, die mit dem REM-Befehl beginnt, wird vom Basicinterpreter ignoriert. Dies gibt Ihnen die Möglichkeit, Ihr Programm mit Erklärungen auszustatten, die Ihnen oder anderen hilft, das Programm zu verstehen. Ein gutes Programm hat am Anfang ein paar REM-Zeilen, in denen der Sinn und Zweck des Programms erklärt wird. Ebenso stehen erklärende Kommentare am Anfang jedes Unterprogramms und überall dort, wo das Programm erklärungsbedürftig ist. Je nach Komplexität des Programms sollte sich der Anteil an REM-Zeilen zwischen 5% und 20% bewegen.

1.2 Programmieren

Der Befehlsmodus ist recht nützlich für einfache Rechenaufgaben - mit Basic-Programmierung hat seine Verwendung aber noch nichts zu tun.

Ein Programm ist eine Abfolge von Befehlen, die durch den Basicinterpreter abgearbeitet werden. Die Befehle stehen dabei in sogenannten Befehlszeilen, wobei jede Zeile normalerweise nur einen Befehl enthält. Die Reihenfolge, in der die Befehlszeilen abgearbeitet werden, wird durch Zeilennummern am Zeilenanfang bestimmt. Das Programm startet bei der kleinsten Zeilennummer und endet bei der größten. Die Nummern müssen nicht fortlaufend sein, es empfiehlt sich sogar, ein Programm zunächst z.B. in Zehnerschritten zu numerieren, um später Zeilen einfügen zu können.

Wenn Sie im Befehlsmodus eine Zeile mit einer Zeilennummer am Anfang eingeben, wird diese nicht sofort ausgeführt sondern gemäß ihrer Zeilennummer an der richtigen Stelle in das im Speicher befindliche Programm eingefügt. Ist der Speicher leer, wird das Programm mit der Eingabe der ersten Programmzeile angelegt.

Existiert bereits eine Zeile mit der Nummer der neu eingegebenen Zeile, so wird die alte kommentarlos durch die neue Zeile ersetzt. Die Eingabe einer Zeilennummer solo löscht eine bereits vorhandene Zeile mit dieser Nummer.

Für die Beispiele in diesem und den folgenden Kapiteln sollen drei einfache Basicbefehle schon an dieser Stelle vorgestellt werden. Sie werden in einem späteren Kapitel noch detailliert besprochen. Den ersten haben Sie schon kennengelernt: Das Fragezeichen im Direktmodus ist eigentlich die Abkürzung eines Basicbefehls, der ausgeschrieben "PRINT" heißt und für Bildschirmausgaben zuständig ist.

Eingaben des Benutzers kann ein Basicprogramm mit dem Befehl "INPUT" anfordern und der Befehl "LET" wird verwendet, um einer Variablen einen Wert zuzuweisen.

Am besten verstehen Sie diese drei Befehle anhand Ihres ersten Basicprogramms:

100 INPUT "GEBEN SIE EINE ZAHL EIN", A
110 LET B=A*A
120 PRINT "DAS QUADRAT VON "; A; " IST "; B 

Die erste Zeile (Nummer 100) veranlasst den Computer, den Text "GEBEN SIE EINE ZAHL EIN" gefolgt von einem Fragezeichen und einem Eingabecursor auszugeben. Nun wartet der Computer auf die Eingabe einer Zahl. Diese wird dann in der Variablen "A" gespeichert.

In der zweiten Zeile (Nummer 110) wird einer neuen Variable B der Wert A*A zugewiesen. "B" enthält nun also den Wert von "A" im Quadrat.

Die dritte Zeile schließlich gibt den Text "DAS QUADRAT VON ", den Wert der Variable A, den Text " IST " und den Wert der Variable B nacheinander aus. Das Semikolon als Trennzeichen bewirkt, daß die Texte und Variableninhalte nahtlos aneinandergehängt werden.

Wenn Sie das Programm mit "RUN" ausführen, passiert auf dem Bildschirm zunächst folgendes:

GEBEN SIE EINE ZAHL EIN? _ 

Nun wartet der Computer auf Ihre Eingabe. Geben Sie nun z.B. eine 5 ein und drücken Sie dann die Eingabetaste. Folgendes steht nun auf dem Bildschirm:

GEBEN SIE EINE ZAHL EIN? 5
DAS QUADRAT VON 5 IST 25

2. Programmstruktur

Im letzten Kapitel wurde ausgeführt, daß ein Programm immer in der Reihenfolge aufsteigender Zeilennummern ausgeführt wird. Das trifft aber nur für sehr einfache Programme zu, die z.B. beim Start ein paar Informationen abfragen und daraus irgendetwas berechnen.

Die meisten Programme erfordern jedoch ein deutlich komplexeres Verhalten. Oft muß ein Programm aufgrund vorgegebener Bedingungen unterschiedlich reagieren, d.h. verschiedene Programmteile abarbeiten. Dies wird als "bedingte Verzweigung" bezeichnet.

Eine andere Form der Strukturierung sind Schleifen, also die mehrfache Abarbeitung eines Programmteils bis zur Erfüllung einer Bedingung.

Eine letzte Variante bei den Strukturbefehlen ermöglicht die Nutzung von Unterprogrammen. Diese können dann jederzeit und von mehreren Stellen des Hauptprogramms aus aufgerufen werden.
Doch eins nach dem anderen:

2.1 Verzweigungen

Bedingungen

Im folgenden wird immer wieder von Bedingungen die Rede sein. Sie sollten daher wissen, wie eine Bedingung aussieht. Basic verfügt für Bedingungen über ein großes Repertoire an Vergleichsoperatoren:

> größer
< kleiner
= gleich
>= größer oder gleich
<= kleiner oder gleich
<> ungleich

Diese funktionieren nicht nur mit Zahlen sondern auch mit Zeichenketten, wobei hier "größer" gleichbedeutend ist mit "steht weiter hinten im Lexikon".

Mehrere Vergleiche können mit den logischen Operatoren "AND", "OR" und "NOT" verknüpft werden. Die Hierarchie der Vergleiche wird im Bedarfsfall mit Klammern festgelegt.
Am besten verstehen Sie die Möglichkeiten auch hier mit Hilfe einiger Beispiele:

 A>=5 

...ist wahr, wenn der Wert der Variable A größer oder gleich 5 ist.

 "Klaus"<"Peter" 

...ist wahr, weil "Klaus" lexikalisch vor "Peter" kommt

 ( A>=5 AND A<=10 ) OR B=1 

...ist wahr, wenn A zwischen 5 und 10 liegt oder B gleich 1 ist.

Verzweigungsbefehle

 GOTO <Zeilennummer> 

Die einfachste Verzweigungsanweisung ist der GOTO-Befehl. Wenn die Programmabarbeitung auf einen GOTO-Befehl stößt, wird das Programm in der angegebenen Zeile fortgesetzt, ohne wenn und aber.
Bei gutem Programmierstil sollte der Einsatz des GOTO-Befehls auf den Ausgleich der Defizite bei anderen Strukturbefehlen in einfachen Basicdialekten beschränkt bleiben (siehe die Beispiele bei IF / THEN und ON GOTO). Wildes Herumspringen im Programm macht es sehr unübersichtlich - dem Basicinterpreter macht das nichts aus, aber der Autor des Programms wird sich nach ein paar Wochen in seinem eigenen Werk nicht mehr zurechtfinden.

Leider war so ein Programmierstil weit verbreitet. Die so entstandenen Programme wurden als "Spaghetticode" bezeichnet.

 IF <Bedingung> THEN <Zeilennummer> 

Die bedingte Verzweigung IF / THEN führt einen Programmteil abhängig von einer Bedingung aus. Trifft die Bedingung zu, wird das Programm ab der hinter THEN angegebenen Zeilennummer fortgesetzt, andernfalls läuft das Programm in der nächsten Zeile (also ganz normal) weiter.

Das folgende Programm berechnet die Quadratwurzel der eingegeben Zahl. Ist die Zahl kleiner als Null, erscheint eine Warnung und das Programm ermöglicht einen neuen Versuch, eine Zahl einzugeben:

100 INPUT "GEBEN SIE EINE POSITIVE ZAHL EIN", A
110 IF A>=0 THEN 140
120 PRINT "DIE ZAHL "; A; "IST NEGATIV!"
130 GOTO 100 140 PRINT "DIE WURZEL VON "; A; " IST "; SQR( A ) 

 ON <Ausdruck> GOTO <Zeilennummer>[, <Zeilennummer][...] 

Mit ON / GOTO können Sie eine Mehrfachverzweigung realisieren. Der Ausdruck wird ausgewertet. Ist das Ergebnis gleich eins, wird zur ersten Zeilennummer der Liste hinter dem GOTO-Befehl gesprungen. Ist das Ergebnis zwei, erfolgt der Sprung zur zweiten der in der Liste aufgeführten Zeilennummern und so weiter.

Das folgende Beispiel zeigt ein einfaches Menü. Sie treffen Ihre Auswahl durch Eingabe einer Nummer:

100 PRINT "WAS MÖCHTEN SIE BESTELLEN?"
110 PRINT "1. ETWAS ZU TRINKEN"
120 PRINT "2. EIN HAUPTGERICHT"
130 PRINT "3. EINEN NACHTISCH"
140 INPUT "GEBEN SIE EINE NUMMER EIN", A
150 ON A GOTO 200, 300, 400
200 PRINT "SIE BEKOMMEN EINE HALBE BIER"
210 GOTO 500
300 PRINT "SIE BEKOMMEN EINE SCHWEINSHAXE MIT SAUERKRAUT"
310 GOTO 500
400 PRINT "SIE BEKOMMEN NOCH EINE HALBE BIER"
500 PRINT "WOHL BEKOMM'S" 

2.2 Schleifen

FOR <Variable>=<Ausdruck> TO <Ausdruck> [STEP <Ausdruck>]
...
NEXT <Variable> 

Bei einer Schleife werden ein oder mehrere Befehle mehrfach ausgeführt. Diese Befehlsgruppe wird eingerahmt durch einen Schleifenbefehl am Anfang und einen am Ende. Bei der FOR/NEXT-Schleife handelt es sich um eine Zählschleife, d.h. bereits der Schleifenbefehl am Anfang legt die Zahl der Schleifendurchläufe fest. Dazu wird einer Variablen das Ergebnis eines Ausdrucks zugewiesen. Diese Variable wird dann mit jedem Durchlauf der Schleife um den hinter "STEP" angegeben Wert erhöht. Fehlt die Angabe von "STEP", wird um eins erhöht.

Die Schleife endet mit dem Erreichen des Wertes, der hinter "TO" angegeben ist.

Zwei Beispiele:

1. Der Computer soll die 7er-Reihe aufsagen:

100 FOR I=7 to 70 STEP 7
110 PRINT I
120 NEXT I 

In der ersten Zeile wird der Variablen "I" zunächst der Wert 7 zugewiesen. Dieser wird in der zweiten Zeile dann auf dem Bildschirm ausgegeben. Die dritte Zeile veranlasst, daß "I" um die Schrittweite 7 erhöht wird und prüft, ob der Endwert 70 bereits erreicht ist. Da dem nicht so ist, wird die Schleife erneut durchlaufen und so der neue Wert von "I", also 14, ausgegeben. Das wird nun so fortgesetzt, bis "I" nach der Erhöhung um 7 den Wert 77 annimmt. Der Endwert 70 ist nun überschritten und die Schleife endet.

2. Der Computer soll das gesamte kleine Einmaleins anzeigen:

100 FOR A=1 TO 10
110 FOR B=1 TO 10
120 PRINT A*B;
130 NEXT B
140 PRINT
150 NEXT A 

Jetzt wird klar, warum beim NEXT-Befehl nochmal der Variablenname steht: Er macht klar, welcher NEXT-Befehl zu welchem FOR-Befehl gehört.

Das Programm beginnt in Zeile 100 mit der Zuweisung des Werts 1 an die Variable "A". In Zeile 110 erhält "B" ebenfalls den Wert 1. Zeile 120 gibt nun den Wert von 1*1 auf dem Bildschirm aus. Das Semikolon am Zeilenende bewirkt, daß die nächste Ausgabe mit PRINT in der gleichen Zeile angehängt wird. In der folgenden Zeile (130) wird nun "B" um eins erhöht, mit dem Endwert 10 verglichen und das Programm in Zeile 120 fortgesetzt. Nun erscheint das Ergebnis von 1*2 auf dem Bildschirm. Dies wiederholt sich nun solange, bis die Schleife mit einem Wert von 10 in der Variable "B" durchlaufen wurde. Nun ist der Endwert erreicht und das Programm geht mit Zeile 140 weiter. Diese macht keine Ausgabe, sondern veranlaßt, daß der nächste PRINT-Befehl seine Ausgabe in einer neuen Bildschirmzeile beginnt.

Nun wird in Zeile 150 der Wert von "A" um eins erhöht, mit dem Endwert für "A" verglichen und das Programm in Zeile 110 fortgesetzt. Dort erhält "B" wieder den Wert 1 und die innere Schleife (Zeilen 110 - 130) läuft wieder von 1 bis 10 und gibt dabei die Zweierreihe auf dem Bildschirm aus. Das Spiel wiederholt sich solange, bis auch "A" den Endwert erreicht hat und das geamte kleine Einmaleins auf dem Bildschirm steht.

Weitere Schleifenbefehle

Leider fehlen bei Tiny-Basic weitere Schleifenbefehle, die in der Programmierpraxis jedoch sehr wichtig sind. Man kann sie allerdings durch IF- und GOTO-Befehle simulieren.

REPEAT
...
UNTIL <Bedingung>

Die Befehle zwischen REPEAT und UNTIL werden so lange durchlaufen, bis nach einem Durchlauf die Bedingung zutrifft. Simulieren kann man das in Tiny-Basic so:

100 REM Erste Zeile der Schleife
110 ...
200 IF NOT( <Bedingung> ) THEN 100

Die zweite wichtige Schleifenart ist die WHILE-Schleife. Bei ihr wird die Abbruchbedingung bereits geprüft, bevor die Befehle in der Schleife das erste mal durchlaufen werden. Das sieht in fortgeschritteneren Basic-Dialekten meist so aus:

WHILE <Bedingung>
...
WEND

Auch dies ist einfach zu simulieren:

100 IF NOT( <Bedingung> ) THEN 200
110 ...
190 GOTO 100
200 REM Hier geht's nach der Schleife weiter

2.3 Unterprogramme

GOSUB <Zeilennummer>
RETURN 

Der Befehl "GOSUB" springt zunächst genauso wie "GOTO" einfach zu der angegebenen Zeilennummer und setzt das Programm dort fort. Der Basicinterpreter merkt sich aber, welche Zeile auf die mit dem GOSUB-Befehl folgt. Falls das Programm nun auf einen "RETURN"-Befehl stößt, wird die Programmausführung in der gemerkten Zeile fortgesetzt.

Als Beispiel soll ein Unterprogramm dienen, das einen Text nacheinander zeichenweise auf den Bildschirm schreibt. Machen Sie sich nichts daraus, wenn Sie die folgenden Zeilen noch nicht ganz verstehen - es genügt für's erste zu wissen, daß sie den Inhalt der Stringvariablen "A$" zeichenweise auf den Bildschirm schreiben. Eine Stringvariable ist eine Variable, die Text enthalten kann.

1000 FOR I=1 TO LEN(A$)
1010 PRINT MID$(A$,I,1);
1020 NEXT I
1030 RETURN

Dieses Unterprogramm für sich auszuführen macht keinen Sinn: Erstens hat A$ noch keinen Inhalt, es wird also auch nichts auf den Bildschirm geschrieben. Zweitens würde der Basicinterpreter in Zeile 1030 auf den RETURN-Befehl stoßen, ohne daß er zuvor bei einem GOSUB vorbeigekommen wäre. Das Programm würde daher mit einer Fehlermeldung abbrechen.

Wir benötigen daher noch ein Hauptprogramm, das unser Unterprogramm nutzt. Es kann es nicht nur einmal, sondern beliebig oft und von verschiedenen Stellen aus aufrufen:

100 A$="ACHTUNG! ACHTUNG! HIER SPRICHT DEIN COMPUTER!"
110 GOSUB 1000
120 PRINT
130 A$="IN MEINEM SPEICHER HAT SICH EIN BIT VERKLEMMT."
140 GOSUB 1000
150 PRINT
160 A$="BITTE DREH MICH UM UND KLOPF MIR AUF DEN RUECKEN!"
170 GOSUB 1000
180 PRINT
190 END 

Zeile 190 enthält einen weiteren neuen Befehl: END. Er führt dazu, daß das Programm an dieser Stelle beendet wird. Es gilt als ordentlicher Programmierstil, alle Unterprogramme am Ende des Programmes (d.h. bei den hohen Zeilennummern) unterzubringen. Das davorstehende Hauptprogramm endet dann mit dem END-Befehl, andernfalls wird zuletzt das erste Unterprogramm nach dem Hauptprogramm ausgeführt und der Basicinterpreter scheitert am RETURN-Befehl, der dieses Unterprogramm abschließt.

ON <Ausdruck> GOSUB <Zeilennummer>[, <Zeilennummer>][...]
...
RETURN 

ON / GOSUB funktioniert genauso wie ON / GOTO, allerdings wird nicht einfach zu eine der in der Liste angegebenen Zeilennummern gesprungen, sondern an der angesprungenen Zeilennummer wird ein Unterprogramm erwartet, das dann irgendwann mit "RETURN" zu der auf den ON/GOTO-Befehl folgenden Zeile zurückkehrt.

3. Arithmetik und Variablen

3.1 Variablen

In den letzten Kapiteln war schon mehrfach von Variablen die Rede. Nun wollen wir sie etwas genauer betrachten. Sie kennen Variablen aus der Mathematik als Platzhalter für Zahlen. Man kann mit Variablen ausdrücken, daß eine Formel gilt - unabhängig welche Zahlen man für die darin enthaltenen Variablen einsetzt.

In allen gängigen Programmiersprachen erfüllen Variablen die gleiche Funktion: Sie können stellvertretend für Zahlen angegeben werden. Man kann einer Variablen einen Wert zuweisen. Überall, wo diese Variable dann im Programm vorkommt, wird sie dann so behandelt als stünde da direkt der Wert dieser Variablen.

 [LET] <Variablenname>=<Ausdruck> 

Mit dem LET-Befehl gibt man einer Variablen einen Wert. Hatte diese Variable zuvor bereits einen anderen Wert, so wird dieser überschrieben. Der LET-Befehl kann auch weggelassen werden.

  A=5 

weist also der Variablen A den Wert 5 zu.

Das folgende Beispiel berechnet mit Hilfe der Formel des Pythagoras die Länge der langen Seite (Hypotenuse) eines rechtwinkligen Dreiecks:

100 INPUT "LAENGE DER 1. KATHETE:", A
110 INPUT "LAENGE DER 2. KATHETE:", B
120 C = SQR( A*A + B*B )
130 PRINT "LAENGE DER HYPOTENUSE: "; C

3.2 Rechnen mit Zahlen

Ein Computer wäre kein Computer, könnte er nicht rechnen. Bisher haben Sie in den Programmbeispielen fast nur die Grundrechenarten sehen können. Basic kann aber noch mehr:

Operatoren

Als Operatoren bezeichnet man die normalen mathematischen Rechenzeichen. Neben den bereits vorgestellten "+" (Addition), "-" (Subtraktion), "*" (Multiplikation) und "/" (Division) kennt Basic noch Klammern zur Festlegung der Auswertungsreihenfolge eines Ausdrucks und das "^" als Exponentzeichen.

2*(4+1) ergibt 10
3^2 ergibt 9
5/2 ergibt 2.5

Am Ergebnis des letzten Beispiels sehen Sie, dass Basic auch mit nichtganzen Zahlen umgehen kann. Entgegen der in Deutschland gebräuchlichen Notation wird in Basic jedoch statt dem Komma ein Punkt verwendet.

Funktionen

INT() rundet auf die nächste ganze Zahl ab.

INT( 5.32 ) ergibt 5
INT( -2.3 ) ergibt -3 

ABS() bildet den Betrag.

ABS( 23 ) ergibt 23
ABS( -4 ) ergibt 4 

SIN() errechnet den Sinus. Das Argument wird im Bogenmaß erwartet. Das gleiche gilt für den Cosinus COS() und den Tangens TAN().

SIN( 3.1415 / 2 ) ergibt 1 

SGN() liefert 1 bei positivem Argument, -1 bei negativem Argument und 0, falls das Argument gleich Null ist.

SGN( 0.3 ) ergibt 1
SGN( -1423 ) ergibt -1

SQR() errechnet die Quadratwurzel.

SQR( 16 ) ergibt 4 

LN() bestimmt den natürlichen Logarithmus, EXP() die Exponentialfunktion (d.h. die Eulersche Zahl hoch dem Argument).

LN( 1 ) ergibt 0
EXP( 1 ) ergibt 2.7172... 

DEF FN<name>(<parameter>)=<ausdruck>
FN(<ausdruck>) 

Sie können nicht nur mit den vorgefertigten Basicfunktionen arbeiten. Wenn eine Formel in einem Programm mehrfach benötigt wird, kann es nützlich sein, sie als Funktion zu definieren. Im Gegensatz zu anderen Programmiersprachen ist die Funktionsdefinition in Basic sehr eingeschränkt, sie darf nämlich nur eine einfache Formel enthalten. Programmierer höherer Programmiersprachen kennen Funktionen hingegen als Unterprogramme mit Rückgabewert.
Als Beispiel sei hier eine Sinusfunktion aufgeführt, deren Argument statt im Bogenmaß in Grad angegeben werden kann:

DEF FNSING(x)=SIN(x/PI*180) 

Nun können Sie die neue Funktion mit vorangestelltem "FN" genauso nutzen, wie jede vorgefertigte Basicfunktion auch:

FNSING(90) ergibt 1
FNSING(270) ergibt -1 

3.3 Strings

Strings sind Zeichenketten, d.h. eine Abfolge von Buchstaben, Zahlen oder Sonderzeichen. Es gibt spezielle Variablen, die anstelle von Zahlen Strings als Wert annehmen können. Diese werden als Stringvariablen bezeichnet und durch ein Dollarzeichen am Ende des Variablennamens kenntlich gemacht.

Mit Strings kan man natürlich nicht im herkömmlichen Sinne rechnen. Zumindest die Addition ist jedoch definiert. Sie hängt die "Summanden" einfach aneinander.

A$="DIES IST "
B$="EIN BEISPIEL"
C$=A$+B$
PRINT C$ 

Der PRINT-Befehl schreibt den Wert der Stringvariablen C$ auf den Bildschirm. Es erscheint

 DIES IST EIN BEISPIEL 

Verschiedene Funktionen ermöglichen sehr interessante Anwendungen von Strings:

LEN() ermittelt die Länge eines Strings

 LEN( "HALLO" ) ergibt 5 

LEFT$( <string>, <anzahl zeichen> )
RIGHT$( <string>, <anzahl zeichen> )
MID$( <string>, <ab zeichen nr>, <anzahl zeichen> ) 

Mit diesen Funktionen können Sie Teile von Strings ermitteln. LEFT$ liefert die angegebene Anzahl Zeichen vom Anfang des Strings, RIGHT$ ebenso aber vom Ende des Strings und mit MID$ können Sie die angegebene Anzahl von Zeichen ab einer bestimmten Position im String ausschneiden

LEFT$( "DONAUDAMPFSCHIFF", 5 ) ergibt DONAU
RIGHT$( "DONAUDAMPFSCHIFF", 6 ) ergibt SCHIFF
MID$( "DONAUDAMPFSCHIFF", 6, 5 ) ergibt DAMPF 

Jeder Buchstabe, jede Ziffer und jedes Sonderzeichen wird vom Computer intern als Zahl gespeichert. Welches Zeichen dabei welcher Zahl entspricht, ist in einem Code festgelegt. Etwa die Hälfte dieses Codes ist standardisiert und auf jedem Computer gleich. Dieser Code heißt "ASCII" (american standard code for information interchange).

Mit der ASC()-Funktion können Sie die Zahl ermitteln, die dem ersten Zeichen des angegebenen Strings zugeordnet ist.

ASC( "A" ) ergibt 65 

Die umgekehrte Funktion zu ASC() stellt CHR$() dar. Die angegebene Zahl wird in das zugehörige Zeichen nach dem ASCII-Code umgewandelt.

CHR$( 65 ) ergibt A 

So können Sie sehr einfach ein Programm schreiben, das eine ASCII-Codetabelle auf den Bildschirm schreibt:

100 FOR I=0 TO 255 STEP 4
110 FOR J=0 TO 3
120 PRINT I+J; ":"; CHR$( I+J ); " ";
130 NEXT J
140 PRINT
150 NEXT I 

VAL wandelt einen Zahlenstring in eine Zahl, STR$ tut genau das Gegenteil. Stößt VAL bei der Umwandlung des Strings auf ein Zeichen, das nicht zu einem Zahlenstring paßt, bricht die Wandlung ab.
Auch hier wird die Wirkungsweise wohl am ehesten durch einige Beispiele klar:

VAL( "12" ) ergibt die Zahl 12
VAL( "35.6" ) ergibt die Zahl 35,6
VAL( "23.07.1998" ) ergibt die Zahl 23,07
VAL( "7A12" ) ergibt die Zahl 7 (der Rest läßt sich nicht als Zahl lesen)

STR$( 14.5 ) ergibt den String "14.5"
STR$( 64 ) ergibt den String "64"

3.4 Felder (Arrays)

Oft ist es notwendig, viele gleichartige Informationen in Variablen abzulegen. Der einfachste Weg, dies zu tun ist die Verwendung von Feldvariablen. Einem Variablennamen kann dabei eine vorher festzulegende Anzahl verschiedener Werte zugewiesen werden. Dem Variablennamen wird dabei in eckigen Klammern ein Index mitgegeben, der die verschiedenen möglichen Werte mit Nummern versieht.

DIM <Variablenname>[<Anzahl Feldelemente>] 

Wie gesagt, die Anzahl möglicher verschiedener Werte in einer Feldvariable muß zuvor festgelegt werden. Dazu dient der DIM-Befehl. Er muß im Programm ausgeführt werden, bevor die zugehörige Feldvariable erstmals benutzt wird.

100 DIM U[12]
110 FOR I=1 TO 12
120 PRINT "UMSATZ IM "; I; ". MONAT DES JAHRES:";
130 INPUT U[I]
140 NEXT I
150 FOR I=1 TO 12
160 PRINT I,
170 FOR J=1 TO U[I]
180 PRINT "#";
190 NEXT J
200 PRINT
210 NEXT I 

Das Beispielprogramm definiert in Zeile 100 eine Feldvariable mit 12 Elementen. In den Zeilen 110 bis 140 werden diese dann vom Anwender des Programms mit Werten gefüllt. Der Rest des Programms gibt die eingegebenen Werte dann als Balkendiagramm wieder aus.

3.5 Programminterne Daten

Oftmals werden in einem Programm Daten benötigt, die fest hinterlegt sein sollen, d.h. nicht jedes mal von Neuem abgefragt werden sollen. Basic bietet dafür einen einzigartigen Mechanismus: Beliebige Daten können, durch Komma getrennt, in sogenannten DATA-Zeilen abgelegt werden. Diese können an jeder beliebigen Stelle im Programm stehen. Stößt der Basicinterpreter bei der Programmabarbeitung auf eine DATA-Zeile, so wird diese ignoriert. Üblicherweise stellt man DATA-Zeilen jedoch ans Programmende.

Der Zugriff auf DATA-Zeilen erfolgt durch den READ-Befehl. Dieser ist in der Verwendung stark an den INPUT-Befehl angelehnt. Die Informationen werden jedoch nicht von der Tastatur eingelesen, sondern von vorn nach hinten aus den im Programm vorhandenen DATA-Zeilen. Dieser Vorgang bleibt im Gegensatz zum Einlesen von Daten per INPUT-Befehl auf dem Bildschirm unsichtbar.
Sollen Daten mehrfach gelesen oder selektiv auf bestimmte Datenbereiche zugegriffen werden, so können Sie per RESTORE-Befehl festlegen, ab welcher DATA-Zeilennummer folgende READ-Befehle ihre Daten lesen sollen.

Nochmals im Detail:

DATA <konstante>[,<konstante>][...] 

Hinter dem Data-Befehl folgen eine oder mehrere Konstanten, wobei es sich dabei um Zahlen oder Zeichenketten handeln darf. Die Trennung erfolgt durch Kommas, Zeichenketten sollten in Anführungszeichen eingeschlossen werden.

READ <variablenname>[,<variablenname>][...] 

Die nächste Konstante oder (bei mehreren angegebenen Variablennamen) die nächsten Konstanten aus den DATA-Zeilen werden gelesen und als Wert(e) der/den angegebenen Variablen zugewiesen.
Ein Beispiel dürfte die Verwendung von Read und Data etwas anschaulicher machen. Es handelt sich dabei um eine abgewandelte Fassung des Balkendiagramm-Generators aus der Erklärung des DIM-Befehls:

100 DIM U[12]
110 FOR I=1 TO 12
130 READ U[I]
140 NEXT I
150 FOR I=1 TO 12
160 PRINT I,
170 FOR J=1 TO U[I]
180 PRINT "#";
190 NEXT J
200 PRINT
210 NEXT I
1000 DATA 5, 8, 9, 13, 12, 18, 20, 17, 11, 8, 1, 0 

 RESTORE [zeilennummer] 

Als nächste per READ zu bearbeitende DATA-Zeile wird die mit der angegebenen Zeilennummer (oder die erste darauffolgende DATA-Zeile, falls die angegebene Zeilennummer keine DATA-Zeile enthält) festgelegt. Wird keine Zeilennummer angegeben, liest der nächste READ-Befehl wieder ab der ersten DATA-Zeile des Programms.

Zur Illustration soll hier nochmals eine Variante des Balkendiagramms dienen:

100 DIM U[12]
101 PRINT "DIE UMSATZZAHLEN DER FOLGENDEN JAHRE LIEGEN VOR:"
102 PRINT "[0] 1996, [1] 1997, [2] 1998"
103 INPUT "GEBEN SIE 0, 1 ODER 2 EIN:"; A 
104 RESTORE 1000+A 
105 READ J 
106 PRINT "UMSATZZAHLEN DES JAHRES "; J; ":" 
110 FOR I=1 TO 12 
130 READ U[I] 
140 NEXT I 
150 FOR I=1 TO 12 
160 PRINT I, 
170 FOR J=1 TO U[I] 
180 PRINT "#"; 
190 NEXT J 
200 PRINT 
210 NEXT I 
1000 DATA 1996, 5, 8, 9, 13, 12, 18, 20, 17, 11, 8, 1, 0 
1001 DATA 1997, 3, 7, 11, 17, 12, 16, 21, 22, 18, 11, 10, 9 
1002 DATA 1998, 15, 18, 20, 22, 23, 21, 20, 17, 18, 16, 16, 15

Ein- / Ausgabe

4.1 Textausgabe auf dem Bildschirm

PRINT [<Ausdruck>[;|,[<Ausdruck>]][...]] 

Der PRINT-Befehl ermöglicht die Ausgabe beliebiger Informationen auf den Bildschirm Als <Ausdruck> können Sie entweder Strings, Stringvariablen oder numerische Ausdrücke angeben, wobei letztere vor der Ausgabe ausgerechnet werden. Werden zwei Ausdrücke durch Semikolon getrennt, hängt sie der Printbefehl direkt aneinander. Ein Komma als Trennzeichen lässt eine Lücke. Komma oder Semikolon können auch am Ende des Printbefehls stehen, sie wirken sich darauf aus, wie die Ausgabe des nächsten Printbefehls angefügt wird.

Ein PRINT-Befehl alleine bewirkt einen Zeilenvorschub, d.h. der darauf folgende PRINT-Befehl beginnt mit der Ausgabe eine Zeile tiefer.

4.2 Eingaben über die Tastatur

INPUT ["<Ausgabetext>",]<Variablenname>[,<Variablenname>][...]

Falls angegeben, schreibt der INPUT-Befehl zuerst den Ausgabetext auf den Bildschirm, gefolgt von einem Fragezeichen und dem Eingabecursor. Ohne Ausgabetext produziert INPUT nur ein Fragezeichen und den Cursor. Der Programmbenutzer muß nun die Werte für die angegebenen Variablen in der richtigen Reihenfolge eingeben.

Es ist eine gute Idee, mit jedem INPUT-Befehl nur eine Variable eingeben zu lassen. Das reduziert die Fehleranfälligkeit und gibt Ihnen die Möglichkeit, die Plausibilität jeder einzelnen Eingabe zu prüfen bevor die nächste erfolgt.